Войти

Login to your account

Username *
Password *
Remember Me

Добавление на панель формы поля ввода с надписью

// Процедура добавляет элемент "ПолеВвода_пв_Проект" на страницу панели платежей "ПлатежПрочие"
// Добавление производится на текущую страницу, поэтому вначале и в конце процедуры выбирается нужная страница
//
// Параметры:
//		ИмяЭлемента - <Строка> - имя элемента "поле ввода"
//      Заголовок - <Строка> - заголовок надписи
//      Данные - <Строка> - данные поля ввода
//      ИмяПанели - <Строка> - имя панели
//		ИмяСтраницы - <Строка> - имя страницы, на которую добавляется элемент
Процедура ДобавитьПолеВводаСНадписью(ИмяЭлемента = "ПолеВвода_пв_Проект", Заголовок = "Проект:", Данные = "пв_Проект",
					ИмяПанели = "ПанельПлатежи", ИмяСтраницы = "ПлатежПрочие")
	
	Если ЭлементыФормы.Найти(ИмяЭлемента) = Неопределено Тогда
		
		тмпТекущаяСтраница = ЭлементыФормы[ИмяПанели].ТекущаяСтраница;
		ЭлементыФормы[ИмяПанели].ТекущаяСтраница = ЭлементыФормы[ИмяПанели].Страницы[ИмяСтраницы];
		
		//Надпись и поле ввода
		ЭлементНадпись = ЭлементыФормы.Добавить(Тип("Надпись"), "Надпись"+ИмяЭлемента, Истина, ЭлементыФормы[ИмяПанели]);
		ЭлементНадпись.Заголовок = Заголовок;
		ЭлементНадпись.Лево = 0;
		ЭлементНадпись.Верх = ЭлементыФормы[ИмяПанели].Высота-30; //добавляем элемент слева внизу
		ЭлементНадпись.Высота = 19;
		ЭлементНадпись.Ширина = 130;
		ЭлементНадпись.ЦветФона = ЦветаСтиля.ФонЭпицентра;
		
		ЭлементПолеВвода = ЭлементыФормы.Добавить(Тип("ПолеВвода"), ИмяЭлемента, Истина, ЭлементыФормы[ИмяПанели]);
		ЭлементПолеВвода.Данные = Данные;
		ЭлементПолеВвода.Верх = ЭлементНадпись.Верх;
		ЭлементПолеВвода.Лево = ЭлементНадпись.Лево + ЭлементНадпись.Ширина + 6;
		ЭлементПолеВвода.Ширина = 164;
		ЭлементПолеВвода.Высота = ЭлементНадпись.Высота;
		
		// установка привязок
		ЭлементПолеВвода.УстановитьПривязку(ГраницаЭлементаУправления.Низ,   ЭлементПолеВвода, 		   ГраницаЭлементаУправления.Верх);
		ЭлементПолеВвода.УстановитьПривязку(ГраницаЭлементаУправления.Лево,  ЭлементыФормы[ИмяПанели], ГраницаЭлементаУправления.Лево);
		ЭлементПолеВвода.УстановитьПривязку(ГраницаЭлементаУправления.Право, ЭлементыФормы[ИмяПанели], ГраницаЭлементаУправления.Лево, 
																			ЭлементыФормы[ИмяПанели],  ГраницаЭлементаУправления.Право);
		
		ЭлементыФормы[ИмяПанели].ТекущаяСтраница = тмпТекущаяСтраница;
		
	КонецЕсли; 	
	
КонецПроцедуры

Метки: Обычные формы